“The cause is something to do with creating bitmaps using code (common in the tween classes), and in extreme cases, bitmaps with transparency on Stage. These bitmaps also need tweening or interaction involved to see the bug. FLA files with those elements involved seem to be affected.”

Whatever the case, we don’t have to deal with this annoying bug, just download the fix and you will be testing your movies in no time.
http://download.macromedia.com/pub/flash/updates/10_0_3/Flash_10_0_3_A dobeUpdate.dmg

var _username:String;
var _password:String;
var _apiUrl:String;

private var logIn():void
{
var path:String = _apiUrl +"&"+_username + "&" + _password;
var request:URLRequest = new URLRequest(_path);
_loader = new URLLoader();
_loader.load(request);
}

Then proceeded to ask, “What’s wrong with this code?” Well, I looked over the method and pointed out that the code wasn’t complete, but the engineer replied, just assume that the syntax is correct and all variables needed are present. The only thing that came to mind, when dealing with API’s, is that there is usually some type of security measure, usually in the form of a user token or session variable. I felt like I was being tricked, the only other answer I could provide was to encrypt the string to secure the data passing over the network, and in short, that’s the answer they were looking for. They should have asked, “How would you protect the users login data when submitting it to an API?” Thanks for the trick question, guys, but as you know almost every API has a different strategy in handling security.

Creating secure SWF applications is not an easy task. The best way to protect your sensitive data is to leverage the HTTPS protocol for sending encrypted data instead of performing the encryption within ActionScript code. Unfortunately, we cant always hide behind HTTPS and It is not advisable to permit HTTP content to access HTTPS content.

There are several strategies to encrypt data in SWF web applications. The most popular are hashing algorithms and symmetric and asymmetric ciphers. Hashing algorithms is a method for performing non-reversible encryption that transforms the original text into a unique string, or hash. The hash is non-reversible, meaning it can not be decrypted and is usually stored on disk. This method is usually used as password authentication and storage. Symmetric and asymmetric ciphers are useful when you want to create a reversible encryption of data, however, the secret and private keys for these tools are usually stored in the SWF, which can be exposed using a decompiler. You can try to hide the key from a decompiler by using a flash obfuscation software, tho I have never implemented this method, I can not advise doing so.

This post is not about Flash security, because I’m not a security expert, it’s about base64 encoding.

Exactly what is Base64 encoding? Base64 encoding is a scheme that encodes arbitrary binary data as a string composed from a set of 64 characters. The exact character set can be any 64 distinct ASCII characters, but by far the most common set is “A” through “Z,” “a” through “z,” “0″ through “9,” “+,” and “/.” Base64 encoding is used by many applications to “obscure” data when it travels across the network. Base64 encoding does not implement a cryptographic algorithm to protect sensitive information, yet is often used in many networks and end-user applications to my amazement.

I recently developed a sweepstakes micro-site for a client, which prerequisite was to obscure users personal data over the network. Since base encoding visually hides otherwise easily recognized information, It satisfied the prerequisite, with an understanding that it was not a secure method and the client signed off on it.

I scripted up a quick little demo app which shows you how to use Base64 encoding.

The demo gathers the users input, encodes it in a JSON object, encodes the object using base64, and passes it to the server where a php script receives it, decodes the base64 JSON object and then passes it back to the flash app. As you noticed, I may have added a complexity by using JSON. JSON is your friend, the JSON format is often used for serializing and transmitting structured data over a network connection. It is primarily used to transmit data between a server and web application, serving as an alternative to XML. I have become accustomed to using it over the years, so I just left it in my code, just for clarification you can use a simple string.

Lets take a look at the demo. I created this app in CS4 using the UI flash components. As most flash apps start out, I created a Main document class:

Main.as
/****************************
* Manuel Gonzalez           *
* design@stheory.com        *
* www.stheory.com           *
* www.codingcolor.com       *
*****************************/
package {

    import flash.display.Sprite;
    import fl.controls.Button;
    import fl.controls.TextArea;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;
    import com.stheory.view.LoginForm;
    import com.stheory.business.LoginProxy;

    public class Main extends Sprite {



        private var _logInView:LoginForm;
        private var _logInProxy:LoginProxy;
        private var _traceField:TextArea;
        private var _okButton:Button;


        public function Main() {

            showLoginView();
        }
        /*
         Method: showLoginView
         Parameters:
         Returns:  
         */
        private function showLoginView():void {
            _logInView = new LoginForm();
            _logInView.x=20;
            _logInView.y=50;
            _logInView.addEventListener(Event.COMPLETE,submitData);
            addChild(_logInView);
        }
        /*
         Method: removeLoginView
         Parameters:
         Returns:  
         */
        private function removeLoginView():void {
            _logInView.removeEventListener(Event.COMPLETE,submitData);
            _logInView.dispose();
            removeChild(_logInView);
        }
        /*
         Method: submitData
         Parameters:
         event:Event
         Returns:  
         */
        private function submitData(event:Event):void {
            removeLoginView();
            createTraceField();
            var loginObj:Object={username:event.target.username,password:event.target.password,remember:event.target.rememberMe};
            _logInProxy=LoginProxy.getInstance();
            _logInProxy.addEventListener(Event.COMPLETE,logInComplete,false,0,true);
            _logInProxy.addEventListener(Event.CANCEL,logInError,false,0,true);
            _logInProxy.submitFormData(loginObj);
        }
        /*
         Method: logInComplete
         Parameters:
         event:Event
         Returns:  
         */
        private function logInComplete(event:Event):void {
            var results=event.target.scriptResult;
            _traceField.text=results;
            _logInProxy.removeEventListener(Event.COMPLETE,logInComplete);
            _logInProxy.removeEventListener(Event.CANCEL,logInError);
        }
        private function logInError(event:Event):void
        {
            var results= event.target.errorEvent;
            _traceField.text=results;
            _logInProxy.removeEventListener(Event.COMPLETE,logInComplete);
            _logInProxy.removeEventListener(Event.CANCEL,logInError);
        }
        /*
         Method: createTraceField
         Parameters:
         Returns:  
         */
        private function createTraceField():void {

            _traceField = new TextArea();
            _traceField.setSize(350, 100);
            _traceField.move(25, 25);
            addChild(_traceField);
            _okButton = new Button();
            _okButton.width=75;
            _okButton.move(300,135);
            _okButton.label="OK";
            _okButton.setStyle("textFormat", new TextFormat("Arial"));
            _okButton.toggle=true;
            _okButton.addEventListener(MouseEvent.CLICK, okClick,false,0,true);
            addChild(_okButton);
        }
        /*
         Method: okClick
         Parameters:
         event:MouseEvent
         Returns:  
         */
        private function okClick(event:MouseEvent):void {
            removeTraceField();
            showLoginView();
        }
        /*
         Method: removeTraceField
         Parameters:
         Returns:  
         */
        private function removeTraceField():void {
            _okButton.removeEventListener(MouseEvent.CLICK,okClick);
            removeChild(_traceField);
            removeChild(_okButton);
        }






    }
}

The Main.as class simply instantiates a logIn view, logIn proxy and creates a trace/log view to print out the interactions with the server. I’m going to skip the logIn view, just assume that all it does is set up the login UI and dispatches an event when the Submit button is pressed. The class that we will focus on is the LogInProxy.as. I utilize Steve Websters base64 encoder/decoder class and the AS3CoreLib developed by Mike Chambers, Daniel Dura and Christian Cantrell for the JSON encoding.
LogInProxy.as
/****************************
* Manuel Gonzalez           *
* design@stheory.com        *
* www.stheory.com           *
* www.codingcolor.com       *
*****************************/
package com.stheory.business{
    import flash.display.Sprite;
    import flash.events.EventDispatcher;
    import flash.events.IEventDispatcher;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.events.SecurityErrorEvent;
    import flash.net.URLLoader;
    import flash.net.URLLoaderDataFormat;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;
    import com.adobe.serialization.json.JSON;
    import com.utils.Base64;



    public class LoginProxy extends Sprite {

        private static  var _instance:LoginProxy;
        private var _loader:URLLoader;
        private var _formObj:Object;
        private var _encryption:String;
        private var _path:String = "http://www.stheory.com/stheory/downloads/scripts/securityTest.php";
        private var _errorEvent:*;
        private var _testScriptResult:String;
       

        public function LoginProxy(singletonEnforcer:SingletonEnforcer) {
            super();
        }
        /*
         Method: getInstance
         Returns: AppServices
         */
        public static  function getInstance():LoginProxy {
            if (_instance == null) {
                _instance=new LoginProxy(new SingletonEnforcer  );
               
            }
            return _instance;
        }
        ////////////// Getters ///////////////////////
        public function get scriptResult():String
        {
            return "base64 to server :\n" +_encryption + "\n\nResults from Server :\n" + _testScriptResult;
        }
        public function get errorEvent():*
        {
            return _errorEvent;
        }
        //////////////////////////////////////////
        /*
         Method: submitFormData
         Parameters:
         inObj:Object
         Returns:  
         */
        public function submitFormData(inObj:Object):void
        {
            _formObj = inObj;
            encodeAndEncryptData();
            sendData();
        }
        /*
         Method: encodeAndEncryptData
         Parameters:
         Returns:  
         */
        private function encodeAndEncryptData():void {
           
           
            var jStr:String = JSON.encode(_formObj);
            _encryption  = Base64.encode(jStr);

        }
        /*
         Method: sendData
         Parameters:
         Returns:  
         */
        private function sendData():void {

            var dataVars:URLVariables = new URLVariables();
            dataVars.data =  _encryption;

            var request:URLRequest = new URLRequest(_path);

            request.method = URLRequestMethod.POST;
            request.data = dataVars;

            _loader = new URLLoader();
            configureListeners(_loader);

            try {
                _loader.load(request);

            } catch (error:Error) {
                trace("Unable to load URL");
                _errorEvent = error;
                dispatchEvent(new Event(Event.CANCEL))
            }

        }
        /*
         Method: configureListeners
         Parameters:
         dispatcher:IEventDispatcher
         Returns:  
         */
        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }
        /*
         Method: removeListeners
         Parameters:
         dispatcher:IEventDispatcher
         Returns:  
         */
        private function removeListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }
        /*
         Method: completeHandler
         Parameters:
         event:Event
         Returns:  
         */
        private function completeHandler(event:Event):void {
            var result = _loader.data;
            try {
                    _testScriptResult = result.toString()
                    dispatchEvent(new Event(Event.COMPLETE))
                }
             catch (error:Error) {
                _errorEvent = error;
                dispatchEvent(new Event(Event.CANCEL))
            }
            removeListeners(_loader);
            _loader=null;
        }
        /*
         Method: securityErrorHandler
         Parameters:
         event:SecurityErrorEvent
         Returns:  
         */
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            //trace("securityErrorHandler: " + event + " \n\n");
            _errorEvent = event;
            dispatchEvent(new Event(Event.CANCEL))
        }
        /*
         Method: ioErrorHandler
         Parameters:
         event:IOErrorEvent
         Returns:  
         */
        private function ioErrorHandler(event:IOErrorEvent):void {
            //trace("ioErrorHandler: " + event + " \n\n");
            _errorEvent = event;
            dispatchEvent(new Event(Event.CANCEL))
        }

    }
}

internal class SingletonEnforcer {
}

I created the LogInProxy class as a Singleton pattern, because I only want to make one object which will handle the data transaction between the client side and the server. LoginProxy is responsible for the base64 encoding, it also submits the data and reports the results. Review the encodeAndEncryptData() method:

 private function encodeAndEncryptData():void  {
           var jStr:String = JSON.encode(_formObj);
            _encryption  = Base64.encode(jStr);
   }

this is where all the magic happens. You can revise this method to meet your needs, for example remove the option of using JSON and just use a simple string. The SendData method, does what it implies, pretty straight forward. Now, lets take a look at the Php.

The Php script is really simple and was created just for this demo:
<?php
$data= $_POST['data'];
$decoded = base64_decode ($data);
echo "$decoded";
?>

It receives the base64 encoded data, decodes it and prints it back to Flash.

Now, for a sanity check, I would recommend using a packet sniffer that captures network traffic, like Service Capture. Here’s a screenshot of the demo app in action:

As you can see, we successfully passed an encoded string to the Php script, which in return passed back a JSON object.
Its really that easy! I could have gone the extra mile and re-encoded a response in base64 and had Flash decode it, but I’ll leave that up to you.
Enjoy!

Download Source:
Base64 encoding example (4)

Open up the Flash IDE, presumably CS4 but CS3 will do.

Select File->Import->Import to Library..

Select your image to import.
Now navigate to your library.

Double click on the bitmap asset to activate the Bitmap Properties panel:

Navigate down to the linkage properties and select Export For ActionScript. You will notice that the Export in frame 1 checkbox will automatically be selected and the Class textfield will be highlighted. Go ahead and add an identifier string of your choice in the Class textfield and Select OK. Essentially, Flash has generated a linked class by the specified identifier automatically, which will allow you to have access to the Bitmap. All you have left to do is create a base class for your .fla and display your bitmap.

Open up your text editor and create a class like so:

package{
   
    import flash.display.Sprite;
    import flash.display.Bitmap;
   
    public class Main extends Sprite{
   
    private var imageSprite:Sprite;
   
    public function Main(){
       
        imageSprite = new Sprite();//create an image container
        addChild(imageSprite);//add it to the display list
        displayImageFromLibrary();
       
    }
   
   
   
    public function displayImageFromLibrary():void
    {
               //instantiate the bitmap in the library by its identifier
        var libraryImage:Bitmap = new Bitmap(new kfc(0,0));

               //place the image in the image container
        imageSprite.addChild(libraryImage);
    }
   
   
   
   
   
    }
   
}

Save the class as Main.as and make sure its in the same folder as the fla.
Navigate back to the Flash Ide and open the properties panel. Enter Main in the class textfield.

Once the program’s document class has been associated with the .fla we can now compile the program, Select-Control Test Movie. If all went well the desired results should have been achieved.

And there you have it.
Photo by Chris Brennan.
Download Source:
AS3 load Image from library (4)

Why would you want to shorten your Url?

Url shortening makes it easier to include the link in an email or Twitter post without it breaking or taking up space. Bit.ly basically redirects a click from the short url to the destination URL using a A 301 redirect. Bit.ly doesn’t re-use or modify links, so the redirects can be considered permanent. Every bit.ly link has an info page, which reveals the number of related clicks and other relevant data. You can get to the info page simply by adding a “+” sign to the end of the link, for example http://bit.ly/clebaM+ .

Click on the ‘Create Short URL’ button below to display the link.

There you go, a short url link created from the http://www.flickr.com/photos/unaesthetic/4513005444/ long url.

The first thing you need to do, to get the example application up and running, is register with bit.ly to get a free user account and api key.

Now lets take a look at the classes:

Main.as
The Main.as document class sets up the user interface in the flash example. The init() method is where we instantiate the class which communicates with the bit.ly api.

/****************************
* Manuel Gonzalez           *
* design@stheory.com        *
* www.stheory.com           *
* www.codingcolor.com       *
*****************************/
package{
   
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.events.Event;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.net.URLRequest;
    import flash.net.navigateToURL;
    import com.business.Bitly;
   
    public class Main extends Sprite {
       
        private var _bitly:Bitly;
        private var _bitlyCallback:Object;
        private var BITLY_LOGIN:String = "xxxxxxxx";//your own username
        private var BITLY_KEY:String = "xxxxxxxxxxxxxxxxxxxxxxxxxxx";//your Api Key
        private var _createShortUrlButton:Button;
        private var _urlInput:TextInput;
        private var _shortUrl:String;
        private var _displayUrlTextField:TextField;
        private var DEFAULT_URL:String = "http://www.flickr.com/photos/unaesthetic/4513005444/";
       
        public function Main(){
            init();
            _urlInput = ti;// instances are already on stage
            _urlInput.x = 15;
            _urlInput.y = 105;
            _urlInput.width = 300;
            _urlInput.text = DEFAULT_URL;
            _createShortUrlButton = cb;// instances are already on stage
            _createShortUrlButton.label = "Create Short URL";
            _createShortUrlButton.x = _urlInput.x + _urlInput.width + 10;
            _createShortUrlButton.y = _urlInput.y;
            _createShortUrlButton.addEventListener(MouseEvent.CLICK, createButtonOnClick,false, 0, true);
            _createShortUrlButton.buttonMode = true;
            _displayUrlTextField = new TextField();
            _displayUrlTextField.x = 25;
            _displayUrlTextField.y = _urlInput.y + 70;
            _displayUrlTextField.selectable = false;
            _displayUrlTextField.autoSize = TextFieldAutoSize.LEFT;
           
                addChild(_displayUrlTextField);
        //make bitly graphic into button
        bkg.btn.buttonMode = true;
         bkg.btn.addEventListener(MouseEvent.CLICK, bitlyButtonOnClick,false, 0, true);
           
        }
        /*
        Method:init()
        Parameters:
        Returns:
        */
        public function init():void
        {
            _bitly = Bitly.getInstance();
            _bitly.login = BITLY_LOGIN;
            _bitly.apiKey = BITLY_KEY;
        }
        /*
        Method:createButtonOnClick
        Parameters:
        event:MouseEvent
        Returns:
        */
        private function createButtonOnClick(event:MouseEvent):void
        {
            var urlToShorten:String = _urlInput.text;
            createBitlyUrl(urlToShorten);
        }
        /*
        Method:bitlyButtonOnClick
        Parameters:
        event:MouseEvent
        Returns:
        */
        private function bitlyButtonOnClick(event:MouseEvent):void
        {
            var URLReq:URLRequest = new URLRequest("http://bit.ly/m");  
            try {  
             navigateToURL(URLReq, "_blank");  
            } catch (event:Error) {  
            //trace(event);  
            }
        }
        /*
        Method:createBitlyUrl
        Parameters:
        inUrl:String
        Returns:
        */
        private function createBitlyUrl(inUrl:String):void
        {
            _bitly.shortenUrl(inUrl);
            _bitly.addEventListener(Event.COMPLETE,bitlyCompleteHandeler,false, 0, true);
           
        }
        /*
        Method: bitlyCompleteHandeler
        Parameters:
        event:Event
        Returns:
        */
        private function bitlyCompleteHandeler(event:Event):void
        {
            _bitly.removeEventListener(Event.COMPLETE,bitlyCompleteHandeler);
            _shortUrl = _bitly.shortUrl;
            displayShortenUrl();
        }
        /*
        Method: displayShortenUrl
        Parameters:
        Returns:
        */
        private function displayShortenUrl():void
        {
           
            _displayUrlTextField.htmlText = makeClickable(_shortUrl);
           
        }
        /*
        Method: makeClickable
        Parameters:
        inStr:String
        Returns: String
        */
        private function makeClickable(inStr:String):String
        {
            var str:String = inStr;
            var hasLink:Boolean = false;
            var nstr:Array = str.split(' ');
            var len:int = nstr.length;
           
            for( var i:int = 0; i < len; i++ )
            {
               
                var n = (nstr[i]).indexOf("http://");
                if( n > -1 ){
                     nstr[i] ="<font color=\"#0000dd\"><A HREF='"+ nstr[i]+ "' target='_blank'><U>"+ nstr[i]+"</U></A></font>";
                    hasLink = true;
                }
            }
            if(hasLink){
                return nstr.join(' ');
            }else{
                return str;
            }
        }
           
    }
           
}

Bitly.as
The Bitly.as class calls upon the bit.ly api which returns a shorten url. I use the Adobe Serialization classes (included in source download) to handle the default Json format. The Bitly.as class is pretty bare bones, since my only use to date is to shorten a long url.

/****************************
* Manuel Gonzalez           *
* design@stheory.com        *
* www.stheory.com           *
* www.codingcolor.com       *
*****************************/
package com.business{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.HTTPStatusEvent;
    import flash.events.IOErrorEvent;
    import flash.events.SecurityErrorEvent;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import com.adobe.serialization.json.JSON;

    public class Bitly extends Sprite {
        private static  var _instance:Bitly;

        private var _login:String;
        private var _apiKey:String;
        private var _url:String;
        private var _bitlyApi:String="http://api.bit.ly/shorten?version=2.0.1&longUrl=";
        private var _loader:URLLoader;
        private var _shortenUrl:String;

        public function Bitly(singletonEnforcer:SingletonEnforcer) {
        }
        /*
         Method: getInstance
         Returns:Bitly
        */
        public static function getInstance():Bitly {
            if (_instance == null) {
                _instance=new Bitly(new SingletonEnforcer  );
            }
            return _instance;
        }
        ///////////////////////////////////////// setters & getters ///////////////////////
        public function set login(inStr:String):void {
            _login=inStr;
        }
        public function get login():String {
            return _login;
        }
        public function set apiKey(inStr:String):void {
            _apiKey=inStr;
        }
        public function get apiKey():String {
            return _apiKey;
        }
        public function get shortUrl():String {
            return _shortenUrl;
        }
        //////////////////////////////////////////////////////////////////////////////////
        /*
         Method:shortenUrl
         Parameters:
         inUrl:String
         Returns:
         */
        public function shortenUrl(inUrl:String):void {
            _url=escape(inUrl);
            getBitlyURL();
        }
        /*
         Method:getBitlyURL
         Parameters:
         Returns:
         */
        private function getBitlyURL():void {
            var path:String=_bitlyApi + _url + "&login=" + _login + "&apiKey=" + _apiKey;
            _loader=new URLLoader  ;
            configureListeners();
            _loader.load(new URLRequest(path));
        }
        /*
         Method: configureListeners
         Parameters:
         Returns:
         */
        private function configureListeners():void {
            _loader.addEventListener(HTTPStatusEvent.HTTP_STATUS,handleBitlyStatus,false, 0, true);
            _loader.addEventListener(IOErrorEvent.IO_ERROR,handleBitlyError,false, 0, true);
            _loader.addEventListener(SecurityErrorEvent.SECURITY_ERROR,handleBitlyError,false, 0, true);
            _loader.addEventListener(Event.COMPLETE,handleBitlyComplete,false, 0, true);

        }
        /*
         Method: removeListeners
         Parameters:
         Returns:
         */
        private function removeListeners():void {
            _loader.removeEventListener(HTTPStatusEvent.HTTP_STATUS,handleBitlyStatus);
            _loader.removeEventListener(IOErrorEvent.IO_ERROR,handleBitlyError);
            _loader.removeEventListener(SecurityErrorEvent.SECURITY_ERROR,handleBitlyError);
            _loader.removeEventListener(Event.COMPLETE,handleBitlyComplete);

        }
        /*
         Method: handleBitlyComplete
         Parameters:
         event:Event
         Returns:
        */
        private function handleBitlyComplete(event:Event):void {
            removeListeners();
            var bitlyObj:Object = JSON.decode(event.target.data);
            var url = unescape(_url);
            if (bitlyObj.statusCode == "OK") {
                _shortenUrl = bitlyObj.results[url].shortUrl;
                dispatchEvent(new Event(Event.COMPLETE));
            } else {
                trace("ERROR");
            }
            _loader = null;
        }
        /*
         Method: handleBitlyStatus
         Parameters:
         event:HTTPStatusEvent
         Returns:
         */
        private function handleBitlyStatus(event:HTTPStatusEvent):void {
            //trace('BITLY status: ' + event);
        }
        /*
         Method: handleBitlyError
         Parameters:
         event:Event
         Returns:
         */
        private function handleBitlyError(event:Event):void {
            //trace('Getting BITLY url failed with error: ' + event);
        }
    }

}
internal class SingletonEnforcer {
}

I currently used the Bitly class in an application that enabled users to share a custom page via twitter.

FYI I’m using a link to Chris Brennan’s flickr. image.

Enjoy!

Download Source:
Bit.ly AS3 exmaple (28)